NAME

MooX::Role::Parameterized - roles with composition parameters

SYNOPSIS

    package Counter;
    use Moo::Role;
    use MooX::Role::Parameterized;    
    use Types::Standard qw( Str );
    parameter name => (
        is       => 'ro',  # this is mandatory on Moo
        isa      => Str,   # optional type
        required => 1,     # mark the parameter "name" as "required"
    );
    role {
        my ( $p, $mop ) = @_;
        my $name = $p->name; # $p->{name} will also work
    
        $mop->has($name => (
            is      => 'rw',
            default => sub { 0 },
        ));
    
        $mop->method("increment_$name" => sub {
            my $self = shift;
            $self->$name($self->$name + 1);
        });
    
        $mop->method("reset_$name" => sub {
            my $self = shift;
            $self->$name(0);
        });
    };
    
    package MyGame::Weapon;
    use Moo;
    use MooX::Role::Parameterized::With;
    
    with Counter => {          # injects 'enchantment' attribute and
        name => 'enchantment', # methods increment_enchantment ( +1 )
    };                         # reset_enchantment (set to zero)
    
    package MyGame::Wand;
    use Moo;
    use MooX::Role::Parameterized::With;
    with Counter => {         # injects 'zapped' attribute and
        name => 'zapped',     # methods increment_zapped ( +1 )
    };                        # reset_zapped (set to zero)

DESCRIPTION

It is an experimental port of MooseX::Role::Parameterized to Moo.

FUNCTIONS

This package exports the following subroutines: "parameter", "role", "apply_roles_to_target" and "apply".

parameter

This function receive the same parameter as "Moo::has". If present, the parameter hash reference will be blessed as a Moo class. This is useful to add default values or set some parameters as required.

role

This function accepts just one code block. Will execute this code then we apply the Role in the target classand will receive the parameter hash reference + one mop object.

The params reference will be blessed if there is some parameter defined on this role.

The mop object is a proxy to the target class.

It offer a better way to call "has", "after", "before", "around", "with" and "requires" without side effects.

Use "method" to inject a new method and "meta" to access TARGET_PACKAGE->meta

Please use:

  my ($params, $mop) = @_;
  ...
  $mop->has($params->{attribute} =>(...));
  $mop->method(name => sub { ... });
  $mop->meta->make_immutable;

apply

Alias to "apply_roles_to_target"

apply_roles_to_target

When called, will apply the "/role" on the current package. The behavior depends of the parameter list.

This will install the role in the target package. Does not need call "with".

Important, if you want to apply the role multiple times, like to create multiple attributes, please pass an arrayref.

    package FooWith;
    use Moo;
    use MooX::Role::Parameterized::With; # overrides Moo::with
    with "Bar" => {           # apply parameterized role Bar once
        attr => 'baz',
        method => 'run'
    }, "Other::Role" => [     # apply parameterized role "Other::Role" twice
        { ... },              # with different parameters
        { ... },
    ],
    "Other::Role" => { ...},  # apply it again
    "Some::Moo::Role",
    "Some::Role::Tiny";
    has foo => ( is => 'ro'); # continue with normal Moo code

STATIC METHOS

is_role

Returns true if the package is a MooX::Role::Parameterized.

  MooX::Role::Parameterized->is_role("My::Role");

DEPRECATED FUNCTIONS

hasp

Removed

method

Removed

VARIABLES

MooX::Role::Parameterized::VERBOSE

By setting $MooX::Role::Parameterized::VERBOSE with some true value we will carp on certain conditions (method override, unable to load package, etc).

Default is false.

MooX::Role::Parameterized::With

See MooX::Role::Parameterized::With package to easily load and apply roles.

Allow to do this:

    package FooWith;
    use Moo;
    use MooX::Role::Parameterized::With; # overrides Moo::with
    with "Bar" => {           # apply parameterized role Bar once
        attr => 'baz',
        method => 'run'
    }, "Other::Role" => [     # apply parameterized role "Other::Role" twice
        { ... },              # with different parameters
        { ... },
      ],
      "Some::Moo::Role",
      "Some::Role::Tiny";
    has foo => ( is => 'ro'); # continue with normal Moo code

THANKS

FGA <fabrice.gabolde@gmail.com>
PERLANCAR <perlancar@gmail.com>
CHOROBA <choroba@cpan.org>
Ed J <mohawk2@users.noreply.github.com>

LICENSE

The MIT License

 Permission is hereby granted, free of charge, to any person
 obtaining a copy of this software and associated
 documentation files (the "Software"), to deal in the Software
 without restriction, including without limitation the rights to
 use, copy, modify, merge, publish, distribute, sublicense,
 and/or sell copies of the Software, and to permit persons to
 whom the Software is furnished to do so, subject to the
 following conditions:
  
  The above copyright notice and this permission notice shall
  be included in all copies or substantial portions of the
  Software.
   
   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT
   WARRANTY OF ANY KIND, EXPRESS OR IMPLIED,
   INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
   MERCHANTABILITY, FITNESS FOR A PARTICULAR
   PURPOSE AND NONINFRINGEMENT. IN NO EVENT
   SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
   LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
   LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
   TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
   CONNECTION WITH THE SOFTWARE OR THE USE OR
   OTHER DEALINGS IN THE SOFTWARE.

AUTHOR

Tiago Peczenyj <tiago (dot) peczenyj (at) gmail (dot) com>

BUGS

Please report any bugs or feature requests on the bugtracker website