NAME

Type::TinyX::Facets - Easily create a facet parameterized Type::Tiny type

VERSION

version 1.3

SYNOPSIS

 package My::Types;
 
 use Carp;
 use Type::Utils;
 use Type::Library -base,
   -declare => 'MinMax',
   'Bounds', 'Positive';
 
 use Types::Standard -types, 'is_Num';
 
 use Type::TinyX::Facets;
 
 # independent facets
 facet 'min', sub {
     my ( $o, $var ) = @_;
     return unless exists $o->{min};
     croak( "argument to 'min' facet must be a number\n" )
       unless is_Num( $o->{min} );
     sprintf( '%s >= %s', $var, delete $o->{min} );
 };
 
 facet 'max', sub {
     my ( $o, $var ) = @_;
     return unless exists $o->{max};
     croak( "argument to 'max' facet must be a number\n" )
       unless is_Num( $o->{max} );
     sprintf( '%s <= %s', $var, delete $o->{max} );
 };
 
 declare MinMax, as Num, with_facets [ 'min', 'max' ];
 
 # related facets
 facet bounds => sub {
     my ( $o, $var ) = @_;
     return unless exists $o->{max} || exists $o->{min};
     croak( "constraint fails condition: max >= min\n" )
       if exists $o->{max} && exists $o->{min} && $o->{max} < $o->{min};
 
     my @code;
 
     if ( exists $o->{min} ) {
         croak( "argument to 'min' facet must be a number\n" )
           unless is_Num( $o->{min} );
         push @code, sprintf( '%s >= %s', $var, delete $o->{min} );
     }
 
     if ( exists $o->{max} ) {
         croak( "argument to 'max' facet must be a number\n" )
           unless is_Num( $o->{max} );
         push @code, sprintf( '%s <= %s', $var, delete $o->{max} );
     }
 
     return join( ' and ', @code );
 };
 
 declare Bounds, as Num, with_facets ['bounds'];
 
 
 # on-the-fly creation of a facet
 declare Positive, as Num, with_facets [
     'min', 'max',
     positive => sub {
         my ( $o, $var ) = @_;
         return unless exists $o->{positive};
         delete $o->{positive};
         sprintf( '%s > 0', $var );
     },
 ];
 
 1;

And in some other code:

 use My::Types -types;
 use Type::Params qw[ validate ];
 
 validate( [5], MinMax [ min => 2 ] );              # passes
 validate( [5], MinMax [ min => 2, max => 6 ] );    # passes
 
 validate( [5], Bounds [ min => 2 ] );              # passes
 validate( [5], Bounds [ min => 2, max => 6 ] );    # passes
 validate( [5], Bounds [ min => 5, max => 2 ] )
   ;    # fails to construct as min > max
 
 validate( [0], Positive [ positive => 1 ] );    # fails!
 validate( [1], Positive [ positive => 1 ] );    # passes

DESCRIPTION

Type::TinyX::Facets make it easy to create parameterized types with facets.

"Type::Tiny" allows definition of types which can accept parameters:

  use Types::Standard -types;
  my $t1 = Array[Int];
  my $t2 = Tuple[Int, HashRef];

This defines $t1 as an array of integers. and $t2 as a tuple of two elements, an integer and a hash.

Parameters are passed as a list to the parameterized constraint generation machinery, and there is great freedom in how they may be interpreted.

This module makes it easy to create a parameterized type which takes name - value pairs or,facets <https://en.wikipedia.org/wiki/Faceted_classification>. (The terminology is taken from Types::XSD::Lite, to which this module owes its existence.)

  use Type::TinyX::Facets facetize => { -as => "facetise" };

SUBROUTINES

  $coderef->( $options, $name, $facet_name );

  facet 'min',
    sub { my ( $o, $var ) = @_;
          return unless exists $o->{min};
          croak( "argument to 'min' facet must be a number\n" )
            unless is_Num( $o->{min} );
          sprintf('%s >= %s', $var, delete $o->{min} );
      };

   ..., with_facets \@facets, ...

   declare BoundedEvenInt, as Int,
   with_facets [ 'min', 'max',
      even => sub {  my ($o, $var) = @_;
                     return unless exists $o->{even};
                     delete $o->{even};
                     "! ( ${var} % 2 )";
                  },
   ],
   message { "This failed" }
   ;

  @facets = (
      'min',
      positive => sub {  my ($o, $var) = @_;
                         return unless exists $o->{positive};
                         delete $o->{positive};
                         sprintf('%s > 0', $var);
                     }
  );

  facetize @facets,
    declare T1, as Num;

LIMITATIONS

Facets defined in one package are not available to another package.

THANKS

TOBYINK <https://metacpan.org/author/TOBYINK>

The idea and most of the code was lifted from Types::XSD::Lite. Any bugs are definitely mine.

SOURCE

The development version is on GitLab at <https://gitlab.com/djerius/type-tinyx-facets>.

SUPPORT

  https://gitlab.com/djerius/type-tinyx-facets

  https://gitlab.com/djerius/type-tinyx-facets.git

AUTHOR

Diab Jerius <djerius@cpan.org>

COPYRIGHT AND LICENSE

This software is copyright (c) 2017 by Smithsonian Astrophysical Observatory.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.